layouts/default.xsl

   1 <?xml version='1.0' encoding='UTF-8' ?>
   2 <!--
   3   Nick's web site: XHTML output stage
   4
   5   Copyright © 2018-2019 Nick Bowler
   6
   7   This program is free software: you can redistribute it and/or modify
   8   it under the terms of the GNU General Public License as published by
   9   the Free Software Foundation, either version 3 of the License, or
  10   (at your option) any later version.
  11
  12   This program is distributed in the hope that it will be useful,
  13   but WITHOUT ANY WARRANTY; without even the implied warranty of
  14   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15   GNU General Public License for more details.
  16
  17   You should have received a copy of the GNU General Public License
  18   along with this program.  If not, see <https://www.gnu.org/licenses/>
  19 -->
  20 <xsl:stylesheet version='1.0'
  21   xmlns='http://www.w3.org/1999/xhtml'
  22   xmlns:xhtml='http://www.w3.org/1999/xhtml'
  23   xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
  24   xmlns:func='http://exslt.org/functions'
  25   xmlns:f='http://draconx.ca/my-functions'
  26   extension-element-prefixes='func f'
  27   exclude-result-prefixes='xhtml'>
  28
  29 <xsl:import href='layouts/functions.xsl' />
  30
  31 <xsl:output method='xml' encoding='UTF-8' indent='yes'
  32   doctype-public='-//W3C//DTD XHTML 1.1//EN'
  33   doctype-system='http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd' />
  34
  35 <xsl:param name='source-uri'
  36   select='"//git.draconx.ca/gitweb/homepage.git/blob/"' />
  37 <xsl:param name='site-title' select='"The Citrine Citadel"' />
  38 <xsl:param name='section-links' select='//document/section-links' />
  39
  40 <func:function name='f:ends-with'>
  41   <xsl:param name='a' />
  42   <xsl:param name='b' />
  43   <func:result
  44     select='substring($a, string-length($a)-string-length($b)+1)=$b' />
  45 </func:function>
  46
  47 <xsl:template match='node()|@*'>
  48   <xsl:copy><xsl:apply-templates select='node()|@*' /></xsl:copy>
  49 </xsl:template>
  50
  51 <!--
  52   Nokogiri's pretty-printer is a bit weird.  Regardless of the indentation
  53   setting, if an element has no child text nodes then it will be pretty-
  54   printed.  This works by adding arbitrary whitespace to that element, and
  55   then all of its children are eligible to be pretty-printed.
  56
  57   If an element has any text nodes at all, then it is not pretty-printed and
  58   neither are any of its descendents.
  59
  60   Adding arbitrary whitespace to <pre> is bad, so we inject zero-width non-
  61   breaking spaces to prevent this.  This will render fine but the spaces
  62   should be removed before final output to avoid problems with copy+paste.
  63 -->
  64 <xsl:template match='xhtml:pre'>
  65   <xsl:copy>
  66     <xsl:apply-templates select='node()|@*' />
  67     <xsl:text>&#x2060;</xsl:text>
  68   </xsl:copy>
  69 </xsl:template>
  70
  71 <!--
  72   Likewise, adding spaces between consecutive span-level elements where
  73   none existed before won't go over well.
  74 -->
  75 <xsl:template name='glue-preceding-span'>
  76   <xsl:if test='f:element-is-span(preceding-sibling::node()[1])'>
  77     <xsl:text>&#x2060;</xsl:text>
  78   </xsl:if>
  79 </xsl:template>
  80
  81 <xsl:template match='*[f:element-is-span()]'>
  82   <xsl:call-template name='glue-preceding-span' />
  83   <xsl:copy>
  84     <xsl:apply-templates select='node()|@*' />
  85     <xsl:if test='*'>
  86       <!-- avoid breaking within a span element -->
  87       <xsl:text>&#x2060;</xsl:text>
  88     </xsl:if>
  89   </xsl:copy>
  90 </xsl:template>
  91
  92 <!--
  93   Manually strip whitespace-only text nodes so the pretty printer can do its
  94   thing on remaining elements.
  95 -->
  96 <xsl:template match='text()[normalize-space(.) = ""]'>
  97   <xsl:choose>
  98     <!-- preserve anything according to xml:space -->
  99     <xsl:when test='ancestor::*[@xml:space][1][@xml:space="preserve"]'>
 100       <xsl:copy />
 101     </xsl:when>
 102     <!-- preserve anything under <pre> -->
 103     <xsl:when test='ancestor::xhtml:pre'><xsl:copy /></xsl:when>
 104     <!-- preserve whitespace which is the only child node of an element -->
 105     <xsl:when test='count(../node()) = 1'><xsl:copy /></xsl:when>
 106   </xsl:choose>
 107 </xsl:template>
 108
 109 <!-- Clean up whitespace where harmless to do so -->
 110 <xsl:template match='xhtml:p/node()[1][self::text()]'>
 111   <xsl:value-of select='f:strip-leading()' />
 112 </xsl:template>
 113 <xsl:template match='xhtml:p/node()[position()=last()][self::text()]'>
 114   <xsl:value-of select='f:strip-trailing()' />
 115 </xsl:template>
 116
 117 <!-- Add rel attributes to external links -->
 118 <xsl:template match='xhtml:a[starts-with(@href,"http://")
 119                           or starts-with(@href,"https://")
 120                           or starts-with(@href,"//")]'>
 121   <xsl:variable name='domain'
 122     select='substring-before(
 123               concat(translate(substring-after(@href, "//"), ":", "/"), "/"),
 124               "/")' />
 125
 126   <xsl:copy>
 127     <xsl:apply-templates select='@*' />
 128     <xsl:if test='not($domain="draconx.ca"
 129                       or f:ends-with($domain, ".draconx.ca"))'>
 130       <xsl:attribute name='rel'>
 131         <xsl:if test='@rel'>
 132           <xsl:value-of select='@rel' />
 133           <xsl:text> </xsl:text>
 134         </xsl:if>
 135         <xsl:text>external noopener noreferrer</xsl:text>
 136       </xsl:attribute>
 137     </xsl:if>
 138     <xsl:apply-templates select='node()' />
 139   </xsl:copy>
 140 </xsl:template>
 141
 142 <xsl:template match='xhtml:h2[@id]'>
 143   <xsl:variable name='fragment' select='concat("#", @id)' />
 144   <xsl:copy>
 145     <xsl:apply-templates select='node()|@*' />
 146     <xsl:if test='$section-links = "yes"'>
 147       <xsl:text> </xsl:text>
 148       <small class='permalink'>
 149         (<a href='{$fragment}'><xsl:value-of select='$fragment' /></a>)
 150       </small>
 151     </xsl:if>
 152   </xsl:copy>
 153 </xsl:template>
 154
 155 <xsl:template match='copyright'>
 156   <p>
 157     <xsl:text>Copyright © </xsl:text>
 158     <xsl:value-of select='text()' />
 159     <xsl:text>.</xsl:text>
 160   </p>
 161 </xsl:template>
 162
 163 <xsl:template match='license'>
 164   <p>
 165     <xsl:text>Copying and distribution of this material</xsl:text>
 166     <xsl:if test='normalize-space(modification-allowed)="yes"'>
 167       <xsl:text>, with or without modification,</xsl:text>
 168     </xsl:if>
 169     <xsl:text> is permitted under the terms of the </xsl:text>
 170     <a rel='license'>
 171       <xsl:attribute name='href'>
 172         <xsl:value-of select='normalize-space(uri)' />
 173       </xsl:attribute>
 174       <xsl:value-of select='name' />
 175     </a>
 176     <xsl:text>.</xsl:text>
 177   </p>
 178 </xsl:template>
 179
 180 <xsl:template match='source'>
 181   <p>
 182     <xsl:text>This document was compiled from </xsl:text>
 183     <a href='{concat($source-uri, revision, ":", file)}'>
 184       <xsl:value-of select='file' />
 185     </a>
 186     <xsl:text> on </xsl:text>
 187     <xsl:value-of select='compiletime' />
 188     <xsl:text>.</xsl:text>
 189   </p>
 190 </xsl:template>
 191
 192 <xsl:template match='/'>
 193   <html>
 194     <head>
 195       <meta name='viewport' content='width=device-width, initial-scale=1' />
 196       <link rel='stylesheet' type='text/css' href='/style.css' />
 197       <link rel="icon" href="data:," />
 198       <title>
 199         <xsl:variable name='page-title' select='string(/document/title)' />
 200         <xsl:if test='$page-title and $site-title != $page-title'>
 201           <xsl:value-of select='concat($page-title, " – ")' />
 202         </xsl:if>
 203         <xsl:value-of select='$site-title' />
 204       </title>
 205     </head>
 206     <body>
 207       <xsl:apply-templates select='/document/xhtml:html/@*' />
 208
 209       <xsl:if test='/document/hierarchy/parent'>
 210         <p id='sitetitle'>
 211           <small><xsl:value-of select='$site-title' /></small>
 212         </p>
 213         <div id='breadcrumbs'>
 214           <strong>Return to: </strong>
 215           <ul>
 216             <xsl:for-each select='/document/hierarchy/parent'>
 217               <li><a href='{uri}'><xsl:value-of select='name'/></a></li>
 218             </xsl:for-each>
 219           </ul>
 220         </div>
 221         <hr />
 222       </xsl:if>
 223
 224       <xsl:apply-templates select='/document/xhtml:html/node()' />
 225
 226       <hr />
 227       <div id='footer'>
 228         <xsl:apply-templates select='/document/copyright' />
 229         <xsl:apply-templates select='/document/license' />
 230         <xsl:apply-templates select='/document/source' />
 231       </div>
 232     </body>
 233   </html>
 234 </xsl:template>
 235
 236 </xsl:stylesheet>