-dnl Copyright © 2019 Nick Bowler
+dnl Copyright © 2019-2020 Nick Bowler
dnl License GPLv2+: GNU General Public License version 2 or any later version.
dnl This is free software: you are free to change and redistribute it.
dnl There is NO WARRANTY, to the extent permitted by law.
AT_CHECK([$CC $CFLAGS $LDFLAGS $LIBGOBJECT_LIBS -o main str.o main.o])
AT_CLEANUP
+
+dnl Check that dynamic types are accepted and compile OK...
+AT_SETUP([dynamic types])
+AT_KEYWORDS([dynamic])
+
+AT_DATA([test.gob],
+[[class :Test from G:Object (dynamic)
+{
+ public void test(void)
+ {
+ }
+}
+]])
+AT_CHECK([gob2 test.gob])
+
+AT_DATA([main.c],
+[[#include "test.h"
+int main(void)
+{
+ test_register_type(NULL);
+}
+]])
+
+TEST_COMPILE_GOBJECT([test.c], [0], [], [ignore])
+TEST_COMPILE_GOBJECT([main.c], [0], [], [ignore])
+AT_CHECK([$CC $CFLAGS $LDFLAGS $LIBGOBJECT_LIBS -o main test.o main.o])
+
+AT_CLEANUP
+
+dnl Dynamic types: simple test case which checks that we can instantiate a
+dnl dynamic type after registration.
+AT_SETUP([dynamic type registration])
+AT_KEYWORDS([dynamic runtime])
+
+AT_DATA([test.gob],
+[[%{
+#include <stdio.h>
+%}
+class :Test from G:Object (dynamic)
+{
+ public gchar *s = { g_strdup("(nil)") };
+ property STRING s (link);
+
+ public void test(self)
+ {
+ printf("%s\n", self->s);
+ }
+}
+]])
+
+AT_DATA([mod.gob],
+[[%{
+#include "test.h"
+%}
+class :Mod from G:Type:Module
+{
+ override (G:Type:Module) gboolean load(G:Type:Module *m)
+ {
+ test_register_type(m);
+ return TRUE;
+ }
+}
+]])
+
+AT_DATA([main.c],
+[[#include <stdio.h>
+#include "mod.h"
+#include "test.h"
+
+void devnull(const char *a, GLogLevelFlags b, const char *c, gpointer d) { }
+
+int main(void)
+{
+ GTypeModule *m = g_object_new(mod_get_type(), NULL);
+ guint handler;
+ Test *t;
+
+ /* should fail, suppress internal glib logging... */
+ handler = g_log_set_handler("GLib-GObject", G_LOG_LEVEL_MASK, devnull, 0);
+ t = g_object_new(test_get_type(), NULL);
+ if (t != NULL)
+ return EXIT_FAILURE;
+ g_log_remove_handler("GLib-GObject", handler);
+
+ g_type_module_use(m);
+ /* should work now */
+ t = g_object_new(test_get_type(), "s", "Hello, World", (char *)NULL);
+ if (!t)
+ return EXIT_FAILURE;
+
+ test_test(t);
+ return EXIT_SUCCESS;
+}
+]])
+
+AT_CHECK([gob2 mod.gob])
+AT_CHECK([gob2 test.gob])
+TEST_COMPILE_GOBJECT([mod.c], [0], [], [ignore])
+TEST_COMPILE_GOBJECT([test.c], [0], [], [ignore])
+TEST_COMPILE_GOBJECT([main.c], [0], [], [ignore])
+AT_CHECK([$CC $CFLAGS $LDFLAGS $LIBGOBJECT_LIBS -o main mod.o test.o main.o])
+AT_CHECK([./main], [0], [Hello, World
+])
+
+AT_CLEANUP
+
+AT_SETUP([GOB2_CHECK min-version test])
+
+AT_DATA([configure.ac],
+[[AC_PREREQ([2.62])
+AC_INIT([test], [0])
+AC_OUTPUT
+]])
+AT_CHECK([$AUTOCONF && test -f configure || exit 77], [0], [ignore], [ignore])
+
+m4_define([MYVER],
+ m4_bpatsubst(m4_dquote(m4_defn([AT_PACKAGE_VERSION])), [[^][0-9.]]))
+
+m4_define([MYVER_P1], m4_dquote(m4_reverse(m4_unquote(
+ m4_split(m4_defn([MYVER]), [[.]])))))
+m4_define([MYVER_P1], m4_join([.], m4_reverse(
+ m4_eval(m4_car(MYVER_P1)+1), m4_shift(MYVER_P1))))
+
+AT_DATA([test.in], [[@GOB2@
+]])
+
+cat >configure.ac <<EOF
+[m4@&t@_include([$builddir/gob2.m4])]
+[m4@&t@_pattern_forbid([^GOB2_])]
+[AC_INIT([gob2_check], [0])]
+[GOB2_CHECK(]m4_dquote(m4_defn([MYVER]))[)]
+GOB2=\`command -v \$GOB2\`
+[AC_CONFIG_FILES([test])]
+[AC_OUTPUT]
+EOF
+AT_CHECK([$AUTOCONF --force])
+AT_CHECK([./configure], [0], [ignore])
+
+command -v gob2 >expout
+AT_CHECK([cat test], [0], [expout], [ignore])
+
+sed '/GOB2_CHECK/c\
+[GOB2_CHECK(]m4_dquote(m4_defn([MYVER_P1]))[)]' configure.ac >configure.new
+mv -f configure.new configure.ac
+AT_CHECK([$AUTOCONF --force])
+AT_CHECK([./configure], [1], [ignore], [ignore])
+
+AT_CLEANUP