X-Git-Url: http://git.draconx.ca/gitweb/gentoo-fixes.git/blobdiff_plain/aba585b8402533b8054957a97bcb11168646cfc7..1af3b4950d9e72d2439a29c78b58e7c774b419ac:/dev-python/pycairo/pycairo-1.18.2-r1.ebuild

diff --git a/dev-python/pycairo/pycairo-1.18.2-r1.ebuild b/dev-python/pycairo/pycairo-1.18.2-r1.ebuild
new file mode 100644
index 0000000..c596011
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.18.2-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright © 2020 Nick Bowler
+#
+# License GPLv2+: GNU General Public License version 2 or any later version.
+# This is free software: you are free to change and redistribute it.
+# There is NO WARRANTY, to the extent permitted by law.
+#
+# This is a modified version of the original ebuild from Gentoo GNU/Linux,
+# covered by the following copyright and permission notice:
+#
+#   Copyright 1999-2020 Gentoo Authors
+#   Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="threads(+)"
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
+SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="2"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="examples"
+
+# Strong block on old pycairo w/ python2 support because the merge will
+# otherwise not work properly due to replacing a directory with a file.
+
+RDEPEND=">=x11-libs/cairo-1.13.1[svg]
+	!!dev-python/pycairo:0[python_targets_python2_7]"
+DEPEND=$RDEPEND
+
+PATCHES=(
+	"$FILESDIR/$P-no-setuptools.patch"
+	"$FILESDIR/$PN-1.19.1-py39.patch"
+)
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+distutils_enable_tests setup.py
+
+python_test() {
+	einfo "Skipping tests on Python 2 to unblock deps"
+}
+
+python_install() {
+	distutils-r1_python_install \
+		install_pkgconfig --pkgconfigdir="${EPREFIX}/usr/$(get_libdir)/pkgconfig"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}