Add aegisub ebuild.

diff --git a/media-video/aegisub/Manifest b/media-video/aegisub/Manifest
new file mode 100644 (file)
index 0000000..479c592
--- /dev/null
+++ b/media-video/aegisub/Manifest
@@ -0,0 +1,2 @@
+DIST aegisub-2.1.9_pre5585.tar.xz 1656500 RMD160 706c599e688871f3f15992c259c8c10438af6d29 SHA1 877f32d9d280d09fc5aa957a125f94e7897d8f2e SHA256 68b8c073acb0aa20025779138374bbacfb41f056b9ee95d078d2bc2644875a6d
+EBUILD aegisub-2.1.9_pre5585.ebuild 1328 RMD160 524216faf897b1238e94c6ec97e716f9e94fb0e0 SHA1 0007ffb11de407cc116a8374b9d114f886e7d381 SHA256 e3059da14f2409d2e5928e7c06675041425437518221d849b8cdc1cb69bdfbfe

diff --git a/media-video/aegisub/aegisub-2.1.9_pre5585.ebuild b/media-video/aegisub/aegisub-2.1.9_pre5585.ebuild
new file mode 100644 (file)
index 0000000..3882b0d
--- /dev/null
+++ b/media-video/aegisub/aegisub-2.1.9_pre5585.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+
+WX_GTK_VER="2.8"
+inherit autotools eutils wxwidgets
+
+DESCRIPTION="Advanced SSA/ASS subtitle editor"
+HOMEPAGE="http://www.aegisub.net/"
+SRC_URI="http://rion-overlay.googlecode.com/files/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa debug +ffmpeg lua nls openal oss portaudio pulseaudio spell"
+
+RDEPEND="
+       x11-libs/wxGTK:${WX_GTK_VER}[X,opengl,debug?]
+       virtual/opengl
+       virtual/glu
+       >=media-libs/libass-0.9.11[fontconfig]
+       virtual/libiconv
+       >=media-libs/fontconfig-2.4.2
+       media-libs/freetype:2
+
+       alsa? ( media-libs/alsa-lib )
+       portaudio? ( =media-libs/portaudio-19* )
+       pulseaudio? ( media-sound/pulseaudio )
+       openal? ( media-libs/openal )
+
+       lua? ( >=dev-lang/lua-5.1.1 )
+
+       spell? ( >=app-text/hunspell-1.2 )
+       ffmpeg? ( >=media-libs/ffmpegsource-2.13.1 )
+"
+DEPEND="${RDEPEND}
+       dev-util/intltool
+       dev-util/pkgconfig
+       media-gfx/imagemagick
+"
+
+src_prepare() {
+       sh autogen.sh --skip-configure
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               $(use_with alsa) \
+               $(use_with oss) \
+               $(use_with portaudio) \
+               $(use_with pulseaudio) \
+               $(use_with openal) \
+               $(use_with lua) \
+               $(use_with ffmpeg ffms) \
+               $(use_with spell hunspell) \
+               $(use_enable debug) \
+               $(use_enable nls)
+}