dnl Copyright © 2020 Nick Bowler
dnl
dnl License WTFPL2: Do What The Fuck You Want To Public License, version 2.
dnl This is free software: you are free to do what the fuck you want to.
dnl There is NO WARRANTY, to the extent permitted by law.

AT_BANNER([Program tests])

AT_SETUP([gob2 probes])

mkdir bin
cp -P "$srcdir/t/gob2.sh" bin

AT_DATA([test.in],
[[@HAVE_GOB2@
@GOB2@
]])

# Unversioned tests
TEST_CONFIGURE_AC([[DX_PROG_GOB2([], [HAVE_GOB2=yes], [HAVE_GOB2=no])
AC_SUBST([GOB2])
AC_SUBST([HAVE_GOB2])

set x conftest*; shift
if test -f $[]1; then
  AC_MSG_ERROR([conftest* left behind by [DX_PROG_GOB2]])
fi

AC_CONFIG_FILES([test])
]])
TEST_AUTORECONF

# Check the search via path lookup
save_PATH=$PATH
PATH=$PWD/bin${PATH:+":$PATH"}
TEST_CONFIGURE
AT_CHECK_UNQUOTED([cat test], [0], [yes
gob2
])
PATH=$save_PATH

# Check the search via user override
TEST_CONFIGURE([GOB2="$srcdir/t/gob2.sh"])
AT_CHECK_UNQUOTED([cat test], [0], [yes
$srcdir/t/gob2.sh
])

# Check that a bogus program doesn't come back as valid.
TEST_CONFIGURE([GOB2=true])
AT_CHECK_UNQUOTED([cat test], [0], [no
true
])

# min-version tests
mv configure.ac configure.old
[sed 's/DX_PROG_GOB2(\[\]/DX_PROG_GOB2([2.1.3]/' configure.old >configure.ac]
TEST_AUTORECONF

FAKE_GOB2_VERSION=2.0.0
export FAKE_GOB2_VERSION
TEST_CONFIGURE([GOB2="$srcdir/t/gob2.sh"])
AT_CHECK_UNQUOTED([cat test], [0], [no
$srcdir/t/gob2.sh
])

FAKE_GOB2_VERSION=3.0.0
TEST_CONFIGURE([GOB2="$srcdir/t/gob2.sh"])
AT_CHECK_UNQUOTED([cat test], [0], [yes
$srcdir/t/gob2.sh
])

FAKE_GOB2_VERSION=2.5.0
TEST_CONFIGURE([GOB2="$srcdir/t/gob2.sh"])
AT_CHECK_UNQUOTED([cat test], [0], [yes
$srcdir/t/gob2.sh
])

FAKE_GOB2_VERSION=2.1.2
TEST_CONFIGURE([GOB2="$srcdir/t/gob2.sh"])
AT_CHECK_UNQUOTED([cat test], [0], [no
$srcdir/t/gob2.sh
])

FAKE_GOB2_VERSION=2.1.3
TEST_CONFIGURE([GOB2="$srcdir/t/gob2.sh"])
AT_CHECK_UNQUOTED([cat test], [0], [yes
$srcdir/t/gob2.sh
])

AT_CLEANUP